xPasos - TODO POR PASOS

my_list_max(X, [X]) :- 
          !.

my_list_max(X, [X|Ys]) :- 
          my_list_max(X1, Ys), 
          X >= X1, 
          !.

my_list_max(X, [_|Xs]) :- 
          my_list_max(X, Xs).

?- my_list_max(X, [5,3,9,2,8,7]).

X = 9

my_list_min(X, [X]) :- 
          !.

my_list_min(X, [X|Ys]) :- 
          my_list_min(X1, Ys), 
          X =< X1, 
          !.

my_list_min(X, [_|Xs]) :- 
          my_list_min(X, Xs).

?- my_list_min(X, [5,3,9,2,8,7]).

X = 2

my_remove_last_element([_], []).

my_remove_last_element([Y|Ys], [Y|Zs]):-
          my_remove_last_element(Ys, Zs).

?- my_remove_last_element([a,b,c,b,e,b,f,g], Zs).

Zs = [a,b,c,b,e,b,f]

my_permutation(Bs, [A|As]):-
          my_append(Xs, [A|Ys], Bs), 
          my_append(Xs, Ys, Zs),
          my_permutation(Zs, As).

my_permutation([], []).

?- my_permutation([a,b,c],Ls).

Ls = [a,b,c]
Ls = [a,c,b]
Ls = [b,a,c]
Ls = [b,c,a]
Ls = [c,a,b]
Ls = [c,b,a]

my_flatten(X, [X]):- 
          \+ list(X).

my_flatten([], []).

my_flatten([As|Bs], Cs):-
          my_flatten(As, ALs),
          my_flatten(Bs, BLs),
          my_append(ALs, BLs, Cs).

?- my_flatten([1,7,3,4,[5,[[[6],[8]],9,7]],[[8],9],[[[0]]]], Ls).

Ls = [1,7,3,4,5,6,8,9,7,8,9,0]

my_bubble_sort(Xs, Ys):-
          my_append(Cs, [A,B|Ds], Xs),
          B < A,
          my_append(Cs, [B,A|Ds], Fs),
          my_bubble_sort(Fs, Ys),
          !.

my_bubble_sort(Xs, Xs).

?- my_bubble_sort([4,7,1,3,2,9,2,6], Ls).

Ls = [1,2,2,3,4,6,7,9]

my_intersect([], _, []).

my_intersect([A|As], Bs, [A|Cs]):-
          my_member(A, Bs),
          !,
          my_intersect(As, Bs, Cs).

my_intersect([_|As], Bs, Cs):-
          my_intersect(As, Bs, Cs).

?- my_intersect([1,2,3,4], [2,3,6,7,1], Ls).

Ls = [1,2,3]

my_union([], Cs, Cs).

my_union([A|As], Bs, Cs):-
          my_member(A, Bs),
          !,
          my_union(As, Bs, Cs).

my_union([A|As], Bs, [A|Cs]):-
          my_union(As, Bs, Cs).

?- my_union([a,b,c], [b,a,d,e,h], Ls).

Ls = [c,b,a,d,e,h]

my_sub_list(Xs, Ys):-
          my_append(_, Bs, Ys),
          my_append(Xs, _, Bs).

?- my_sub_list([b,c], [a,b,c,d,e,f,g]).

yes

?- my_sub_list([b,c,f], [a,b,c,d,e,f,g]).

no

?- my_sub_list(Ls, [c,d,e]).

Ls = [] ;
Ls = [c] ;
Ls = [c,d] ;
Ls = [c,d,e] ;
Ls = [] ;
Ls = [d] ;
Ls = [d,e] ;
Ls = [] ;
Ls = [e] ;
Ls = [] ;

my_list_max(M, [X|Xs]):-
          my_list_max2(M, X, Xs).

my_list_max2(M, M, []):- !.

mylist_max2(X, Y, [Z|Zs]):-
          Z >= Y,
          !,
          my_list_max2(X, Z, Zs).

my_list_max2(X, Y, [Z|Zs]):-
          Z =< Y,
          my_list_max2(X, Y, Zs).

?- my_list_max(M, [5,3,9,2,8,7]).

M = 9

my_list_min(M, [X|Xs]):-
         my_list_min2(M, X, Xs).

my_list_min2(M, M, []):- !.

my_list_min2(X, Y, [Z|Zs]):-
          Z =< Y,
          !,
          my_list_min2(X, Z, Zs).

my_list_min2(X, Y, [Z|Zs]):-
          Z >= Y,
          my_list_min2(X, Y, Zs).

?- my_list_min(M, [5,3,9,2,8,7]).

M = 2

my_palindrome(Xs):-
          my_reverse(Xs, Xs).

?- my_palindrome([a,b,c,d,e,d,c,b,a]).

yes

?- my_palindrome([a,b,c,d,e]).

no

my_reverse([X|Xs], Ys, Zs):-
          my_reverse(Xs, [X|Ys], Zs).

my_reverse([], Ys, Ys).

?- my_reverse([1,2,3,4,5], [], Ls).

Ls = [5,4,3,2,1]

my_reverse([], []).

my_reverse([X|Xs], Ys):-
          my_reverse(Xs, Zs),
          my_append(Zs, [X], Ys).

?- my_reverse([1,2,3,4,5], Ls).

Ls = [5,4,3,2,1]

my_consecutive(X,Y,[X,Y|_]).

my_consecutive(X,Y,[_|Xs]):-
          my_consecutive(X,Y,Xs).

?- my_consecutive(e,g,[d,f,e,g,h,e,r,u]).

yes

?- my_consecutive(g, e, [d,f,e,g,h,e,r,u]).

no

my_remove_element_n(_, _, [], []).

my_remove_element_n(N, N, [_|Xs], Zs):-
          I2 is N + 1,
          my_remove_element_n(N, I2, Xs, Zs), !.

my_remove_element_n(N, I, [Y|Xs], [Y|Zs]):-
          I2 is I + 1,
          my_remove_element_n(N, I2, Xs, Zs).

?- my_remove_element_n(5, 1, [a,b,c,d,e,f,g,h], Zs).

Zs = [a,b,c,d,f,g,h]

my_remove_element_n(1, [_|Xs], Xs).

my_remove_element_n(I, [X|Xs], [X|Ys]):-
          I2 is I - 1,
          my_remove_element_n(I2, Xs, Ys).

?- my_remove_element_n(5, [a,b,c,d,e,f,g,h], Zs).

Zs = [a,b,c,d,f,g,h]

my_compress([], []):- !.

my_compress([X|Xs], Ys):-
          my_member(X, Xs),
          !,
          my_compress(Xs, Ys).

my_compress([X|Xs], [X|Ys]):-
          my_compress(Xs, Ys).

?- my_compress([a,a,e,e,e,c,c,b,b,b,b,d,f], Ls).

Ls = [a,e,c,b,d,f]

?- my_compress([e,e,e,a,a,e,e,e,c,c,b,b,b,b,d,f], Ls).

Ls = [a,e,c,b,d,f]

my_compress([], []).

my_compress([X], [X]).

my_compress([X, X|Xs], Zs):-
          my_compress([X|Xs], Zs).

my_compress([X, Y|Ys], [X|Zs]):-
          X \= Y,
          my_compress([Y|Ys], Zs).

?- my_compress([a,a,e,e,e,c,c,b,b,b,b,d,f], Ls).

Ls = [a,e,c,b,d,f]

?- my_compress([e,e,e,a,a,e,e,e,c,c,b,b,b,b,d,f], Ls).

Ls = [e,a,e,c,b,d,f]

my_average(Xs, A):-
          my_length(Xs, L),
          my_sum_elements(Xs, S),
          A is S / L.

?- my_average([1,2,3,4,5,6], A).

A = 3.5